Kiến thức cơ bản: Cách UNIQUE thường hoạt động
Hàm UNIQUE của Excel có sẵn trong các phiên bản Excel độc lập từ 2021 trở lên, Excel cho Microsoft 365, Excel cho web và các ứng dụng di động/tablet mới nhất. Cú pháp của nó như sau:
=UNIQUE(mảng,[theo_cột],[chính_xác_một_lần])
Trong đó:
- mảng (bắt buộc): Phạm vi hoặc bảng chứa dữ liệu cần lấy giá trị duy nhất.
- theo_cột (tùy chọn): Đặt là TRUE để so sánh theo cột (mặc định FALSE – so sánh theo hàng).
- chính_xác_một_lần (tùy chọn): Đặt là TRUE để chỉ trả về các giá trị xuất hiện đúng một lần (mặc định FALSE – trả về mọi giá trị riêng biệt).
UNIQUE là một hàm mảng động. Bạn chỉ cần nhập công thức vào một ô, kết quả sẽ tự động “tràn” (spill) sang các ô bên cạnh. Bạn sẽ thấy một đường viền xanh lam bao quanh vùng kết quả. Nếu có vật cản, lỗi #SPILL! sẽ xuất hiện.
Trích xuất các cột liền kề
Giả sử bạn theo dõi chi tiêu gia đình trong bảng T_ChiTieu và muốn liệt kê mọi tổ hợp duy nhất giữa “Danh mục” và “Cửa hàng”.
Vì hai cột này liền kề, bạn có thể kết hợp chúng bằng dấu hai chấm:
=UNIQUE(T_ChiTieu[[Danh mục]:[Cửa hàng]])
Vấn đề khi trích xuất các cột không liền kề
Bây giờ, nếu bạn muốn lấy tổ hợp duy nhất giữa “Danh mục” và “Phương thức” – hai cột không liền kề.
Nếu thử chọn riêng từng cột trong công thức UNIQUE, bạn sẽ gặp lỗi #VALUE!. Lý do là UNIQUE cần một mảng dữ liệu liên tục. Khi bạn chọn hai cột riêng biệt bằng dấu phẩy, Excel sẽ nhầm cột thứ hai thành đối số theo_cột (vốn cần giá trị TRUE/FALSE), gây ra lỗi.
Dưới đây là hai cách khắc phục.
Giải pháp nhanh: Kết hợp CHOOSECOLS bên trong UNIQUE
Để bỏ qua cột, bạn cần tạo một mảng dữ liệu ảo chỉ chứa những cột mong muốn. Hàm CHOOSECOLS làm được điều này — nó cho phép chọn cột cụ thể từ một bảng dựa trên số thứ tự.
Trong bảng T_ChiTieu, “Danh mục” là cột 2 và “Phương thức” là cột 4. Công thức như sau:
=UNIQUE(CHOOSECOLS(T_ChiTieu,2,4))
CHOOSECOLS sẽ lấy toàn bộ bảng T_ChiTieu, nhưng chỉ giữ lại cột 2 và 4 để tạo thành mảng mới, rồi chuyển cho UNIQUE xử lý.
Giải pháp linh hoạt: Dùng MATCH để tham chiếu động
Phương pháp CHOOSECOLS có một điểm yếu: nó dùng số cột cố định. Nếu bạn chèn thêm cột mới vào bảng, vị trí cột sẽ thay đổi và công thức có thể cho kết quả sai.
Để công thức tự động thích ứng, hãy dùng hàm MATCH để tìm số thứ tự cột dựa trên tên tiêu đề:
=UNIQUE(
CHOOSECOLS(
T_ChiTieu,
MATCH(G1,T_ChiTieu[#Headers],0),
MATCH(H1,T_ChiTieu[#Headers],0)
))
Nhấn Alt+Enter khi nhập trong thanh công thức để xuống dòng, giúp công thức dễ đọc hơn.
Trong công thức này, MATCH sẽ tìm chữ trong ô G1 (ví dụ: “Danh mục”) và ô H1 (ví dụ: “Phương thức”) trong hàng tiêu đề của bảng (T_ChiTieu[#Headers]). Số 0 yêu cầu khớp chính xác. Hàm sẽ trả về số thứ tự của cột đó (2 và 4) cho CHOOSECOLS.
Giải pháp này linh hoạt hơn vì:
- Tự do cấu trúc: Bạn có thể di chuyển hoặc chèn cột. MATCH luôn tìm đúng tên tiêu đề.
- Tránh lỗi: Loại bỏ rủi ro đếm sai số cột trong bảng lớn.
- Tùy chọn linh hoạt: Chỉ cần thay đổi tên cột trong ô G1 và H1, danh sách duy nhất sẽ tự cập nhật.
Mẹo chuyên nghiệp: Tạo menu chọn tiêu đề bằng INDIRECT
Để trực quan và tránh lỗi chính tả, bạn có thể biến ô G1 và H1 thành menu thả xuống chứa các tiêu đề cột.
Tuy nhiên, công cụ Xác thực Dữ liệu (Data Validation) của Excel không hỗ trợ trực tiếp tham chiếu có cấu trúc như T_ChiTieu[#Headers]. Bạn có thể dùng hàm INDIRECT để chuyển chuỗi văn bản thành tham chiếu hợp lệ.
Đầu tiên, chọn ô G1 và H1. Vào Data (Dữ liệu) > Data Validation (Xác thực Dữ liệu).
Trong hộp thoại, chọn Allow (Cho phép) là List (Danh sách), và nhập công thức sau vào Source (Nguồn):
=INDIRECT("T_ChiTieu[#Headers]")
Nhấn OK. Bây giờ, ô G1 và H1 sẽ có mũi tên thả xuống liệt kê tất cả tiêu đề cột trong bảng T_ChiTieu.
Khi bạn chọn tên cột khác từ menu, MATCH sẽ tìm vị trí mới, CHOOSECOLS lấy dữ liệu và UNIQUE cập nhật kết quả ngay lập tức. Mọi cột mới thêm vào bảng cũng sẽ tự động xuất hiện trong menu này.
So với công cụ “Xóa Trùng lặp” (Remove Duplicates) có thể làm mất dữ liệu gốc, hàm UNIQUE với mảng động là cách xử lý dữ liệu an toàn và hiệu quả hơn. Với thiết lập trên, dữ liệu gốc của bạn được giữ nguyên, trong khi bản tóm tắt các giá trị duy nhất luôn chính xác dù bạn có sắp xếp lại bảng tính.
Tags: Excel Hàm UNIQUE, Xử lý dữ liệu Excel, Công thức Excel nâng caoExcel Hàm UNIQUE, Xử lý dữ liệu Excel, Công thức Excel nâng cao
